sub:assertion {
  sub:get-publisher-version dct:description "This query returns the final publisher version of the given nanopublication, or an empty result if no such version is found." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Returns the final publisher version of the given nanopublication" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/meta> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/terms/>
prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix nt: <https://w3id.org/np/o/ntemplate/>
prefix bibo: <http://purl.org/ontology/bibo/>
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
prefix prov: <http://www.w3.org/ns/prov#>

select ?publisher_version_np ?npType ?journalName where {

graph npa:graph {
  bind(replace(str(?_np_iri), \"^.*[^a-zA-Z0-9-_](RA[a-zA-Z0-9-_]{43})$\", \"$1\") as ?ac)
  ?np npa:artifactCode ?ac .
}

values (?npType ?journalName ?pubkeys) {
  (<https://w3id.org/kpxl/pensoft/rio/terms/RIOJournalNanopub> \"RIO Journal\" \"1162349fdeaf431e71ab55898cb2a425b971d466150c2aa5b3c1beb498045a37 cfe248c38933693b1ddeb62e17976a4d2396b0c738af5356bfffbe559d1a3de0 170211c91a70e67992d52c760de3f0052c8c7271bd3c225ef0347245e8517ff6\")
  (<https://w3id.org/kpxl/pensoft/bdj/terms/BiodiversityDataJournalNanopub> \"Biodiversity Data Journal\" \"1162349fdeaf431e71ab55898cb2a425b971d466150c2aa5b3c1beb498045a37 cfe248c38933693b1ddeb62e17976a4d2396b0c738af5356bfffbe559d1a3de0 170211c91a70e67992d52c760de3f0052c8c7271bd3c225ef0347245e8517ff6\")
  (<https://w3id.org/kpxl/ios/ds/terms/DataScienceNanopub> \"Data Science\" \"1162349fdeaf431e71ab55898cb2a425b971d466150c2aa5b3c1beb498045a37 cfe248c38933693b1ddeb62e17976a4d2396b0c738af5356bfffbe559d1a3de0 170211c91a70e67992d52c760de3f0052c8c7271bd3c225ef0347245e8517ff6\")
}

bind(?__type_iri as ?t)
filter(!bound(?t) || ?t = ?npType)

bind(uri(concat(\"https://w3id.org/np/l/nanopub-query-1.1/repo/type/\", sha256(str(?npType)))) as ?service)
service ?service {
  graph npa:graph {
    ?publisher_version_np npa:hasValidSignatureForPublicKey ?pubkey .
    ?publisher_version_np np:hasPublicationInfo ?i .
    filter not exists { ?publisher_version_np npx:hasNanopubType npx:ExampleNanopub . }
    filter not exists { ?npx npx:invalidates ?publisher_version_np ; npa:hasValidSignatureForPublicKey ?pubkey . }
    filter(contains(?pubkeys, sha256(?pubkey)))
  }
  graph ?i {
    ?publisher_version_np prov:wasDerivedFrom ?np .
  }
}

}""" .
}