sub:assertion {
  sub:get-fip-supercommunities dct:description "This query returns a list of all FIP communities that have supercommunities." ;
    dct:license <http://www.apache.org/licenses/LICENSE-2.0> ;
    a <https://w3id.org/kpxl/grlc/grlc-query> ;
    rdfs:label "Get FIP supercommunities" ;
    <https://w3id.org/kpxl/grlc/endpoint> <https://w3id.org/np/l/nanopub-query-1.1/repo/full> ;
    <https://w3id.org/kpxl/grlc/sparql> """prefix rdfs: <http://www.w3.org/2000/01/rdf-schema#>
prefix dct: <http://purl.org/dc/terms/>
prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix fip: <https://w3id.org/fair/fip/terms/>

select distinct ?community (group_concat(distinct ?supercommunity; separator=\" \") as ?supercommunities) (group_concat(distinct ?sc; separator=\" \") as ?sc) where {
  graph npa:graph {
    ?np npa:hasValidSignatureForPublicKey ?pubkey .
    filter not exists { ?npx npx:invalidates ?np ; npa:hasValidSignatureForPublicKey ?pubkey . }
    ?np npx:hasNanopubType fip:FAIR-Implementation-Community .
    ?np (npx:introduces|npx:describes) ?community .
    ?np np:hasAssertion ?a .
  }
  graph ?a {
    ?community dct:isPartOf ?supercommunity .
  }
  optional {
    graph npa:graph {
      ?disapproval np:hasAssertion ?da .
      ?disapproval npa:hasValidSignatureForPublicKey ?dpubkey .
      filter not exists { ?disapproval_x npx:invalidates ?disapproval ; npa:hasValidSignatureForPublicKey ?dpubkey . }
    }
    graph <https://w3id.org/np/RAkVk6aKWsmgcuKtPA7OSp2h-GbDfx8xrz_kJAAgY8Xa4#assertion> {
      ?dpubkeys npx:hasPublicKey ?dpubkey .
    }
    graph ?da {
      ?dsomebody ( npx:disapproves-of | npx:disapprovesOf ) ?np .
    }
  } filter(!bound(?disapproval))  # for some reason this is much faster than \"filter not exists\"
  bind(replace(str(?supercommunity), \".*#\", \"\") as ?sc)
} group by ?community""" .
}